#===============================================================================
# Copyright (C) 2025 Intel Corporation
#
# This software and the related documents are Intel copyrighted  materials,  and
# your use of  them is  governed by the  express license  under which  they were
# provided to you (License).  Unless the License provides otherwise, you may not
# use, modify, copy, publish, distribute,  disclose or transmit this software or
# the related documents without Intel's prior written permission.
#
# This software and the related documents  are provided as  is,  with no express
# or implied  warranties,  other  than those  that are  expressly stated  in the
# License.
#===============================================================================

cmake_minimum_required(VERSION 3.13)

if(WIN32)
  message(FATAL_ERROR "sycl_mpi examples are not supported on Windows platform.")
endif()

enable_testing()

# Set MKL_ROOT directory
function(define_mkl_root POTENTIAL_MKL_ROOT)
  if(EXISTS "${POTENTIAL_MKL_ROOT}/include/mkl.h")
    set(MKL_ROOT "${POTENTIAL_MKL_ROOT}" PARENT_SCOPE)
  else()
    set(MKL_ROOT "" PARENT_SCOPE)
  endif()
endfunction()

if("${MKL_ROOT}" STREQUAL "")
  if(NOT "$ENV{MKLROOT}" STREQUAL "")
    file(TO_CMAKE_PATH "$ENV{MKLROOT}" POTENTIAL_MKL_ROOT)
    define_mkl_root("${POTENTIAL_MKL_ROOT}")
  endif()
  if("${MKL_ROOT}" STREQUAL "" AND (NOT "${MKL_DIR}" STREQUAL ""))
    get_filename_component(POTENTIAL_MKL_ROOT "${MKL_DIR}/../../../" ABSOLUTE)
    define_mkl_root("${POTENTIAL_MKL_ROOT}")
  endif()
  if("${MKL_ROOT}" STREQUAL "")
    get_filename_component(MKL_CMAKE_PATH "${CMAKE_CURRENT_SOURCE_DIR}" REALPATH)
    get_filename_component(POTENTIAL_MKL_ROOT "${MKL_CMAKE_PATH}/../../../../../" ABSOLUTE)
    define_mkl_root("${POTENTIAL_MKL_ROOT}")
  endif()
  if("${MKL_ROOT}" STREQUAL "")
    message(STATUS "Cannot infer MKL_ROOT from the MKLROOT environment variable, MKL_DIR variable, or the directory containing CMakeLists.txt.")
  endif()
endif()
if(NOT "${MKL_ROOT}" STREQUAL "")
  file(TO_CMAKE_PATH "${MKL_ROOT}" MKL_ROOT)
  message(STATUS "MKL_ROOT: ${MKL_ROOT}")
endif()

# Add cmake scripts and modules to CMake search path
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/../cmake")
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
if(NOT "${MKL_ROOT}" STREQUAL "")
  list(APPEND CMAKE_MODULE_PATH "${MKL_ROOT}/share/doc/mkl/examples/cmake")
endif()

set(ENABLE_MPI ON)

# Define language and compiler
set(TEST_LANG CXX)
set(TEST_EXT cpp)
include(setup_examples)

project(MKL_Examples LANGUAGES ${TEST_LANG})
find_package(MKL CONFIG REQUIRED)

# W/A for known problem in Intel(R) MPI Library 2021.1
if(MKL_MPI STREQUAL "intelmpi" AND DEFINED ENV{I_MPI_ROOT})
  if(UNIX AND $ENV{I_MPI_ROOT} MATCHES "2021.1")
    set(MPI_C_ADDITIONAL_INCLUDE_DIRS $ENV{I_MPI_ROOT}/include)
  endif()
endif()

find_package(MPI REQUIRED)

# Generate domainList and ${domain}_funcList
include(generate_examples_list)

# limit C++ errors to one
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ferror-limit=1")

if(FAIL_ON_MISSING_DEVICES)
  list(APPEND DEVICE_OPT -DFAIL_ON_MISSING_DEVICES)
  message(STATUS "FAIL_ON_MISSING_DEVICES: `${FAIL_ON_MISSING_DEVICES}`")
endif()

foreach(device IN LISTS TARGET_DEVICES)
  list(APPEND DEVICE_OPT -DSYCL_DEVICES_${device})
endforeach()

# Define target for each function from each domain
if(domainList)
foreach(domain IN LISTS domainList)
  set(TEST_INCLUDE "")
  set(TEST_LOPT "")
  set(TEST_COPT "")

  list(APPEND TEST_INCLUDE "${PROJECT_SOURCE_DIR}/common" "${PROJECT_SOURCE_DIR}/${domain}")
  list(APPEND TEST_COPT ${DEVICE_OPT})
  # Some tests need this option as well
  if(NOT MKL_LINK STREQUAL "static")
    list(APPEND TEST_LOPT "-fsycl-device-code-split=per_kernel")
  endif()

  set(TEST_ENV "")
  if(NOT DEFINED ENV{I_MPI_OFFLOAD})
    list(APPEND TEST_ENV "I_MPI_OFFLOAD=1")
  endif()
  if(NOT DEFINED ENV{I_MPI_OFFLOAD_IPC_MODE})
    list(APPEND TEST_ENV "I_MPI_OFFLOAD_IPC_MODE=drmfd")
  endif()
  if(NOT DEFINED ENV{I_MPI_OFFLOAD_TOPOLIB})
    list(APPEND TEST_ENV "I_MPI_OFFLOAD_TOPOLIB=level_zero")
  endif()
  if(MKL_ENV)
    list(APPEND TEST_ENV "${MKL_ENV}")
  endif()

  # Build target for each example
  message(STATUS "Functions list ${domain}: ${${domain}_funcList}")
  foreach(func IN LISTS ${domain}_funcList)
    set(executable "${domain}-${func}")

    file(GLOB_RECURSE ${domain}_${func}_SRC ${PROJECT_SOURCE_DIR}/${domain}/*/${func}.${TEST_EXT})
    if(NOT ${domain}_${func}_SRC)
      message(FATAL_ERROR "${domain} source file ${func}.${TEST_EXT} was not found")
    endif()

    add_executable(${executable} ${${domain}_${func}_SRC})
    target_include_directories(${executable} PUBLIC ${TEST_INCLUDE})
    target_compile_options(${executable} PUBLIC ${TEST_COPT})
    target_link_libraries(${executable} PUBLIC ${TEST_LOPT} MKL::MKL_SYCL_DISTRIBUTED_DFT MPI::MPI_CXX)

    # Register example as ctest
    add_test(NAME ${executable} COMMAND ${MPIEXEC_EXECUTABLE} -genvall ${MPIEXEC_NUMPROC_FLAG} 4 ${MPI_LOCAL_OPT} ${PROJECT_BINARY_DIR}/${executable})

    # Add Environment variables
    if(TEST_ENV)
      set_tests_properties(${executable} PROPERTIES ENVIRONMENT "${TEST_ENV}")
    endif()
  endforeach() #${domain}_funcList
endforeach() #domainList
endif() #not empty domainList
