Part
    name = "SP_DEATH_SPORE"
    description = "SP_DEATH_SPORE_DESC"
    class = Bombard
    capacity = 0.5
    mountableSlotTypes = External
    buildcost = 5 * [[FLEET_UPKEEP_MULTIPLICATOR]] * [[SHIP_PART_COST_MULTIPLIER]]
    buildtime = 3
    tags = [ "CTRL_BOMBARD_ORGANIC" "PEDIA_PC_BOMBARD" ]
    location = All
    effectsgroups = [
        EffectsGroup    // players can order death spores used on enemies
            scope = And [
                InSystem id = Source.SystemID
                Planet
                Species
                OrderedBombardedBy condition = Source
                Or [
                    OwnedBy affiliation = EnemyOf empire = Source.Owner
                    Unowned
                ]
                VisibleToEmpire empire = Source.Owner
                /// @content_tag{ORGANIC} When bombarding in-system enemy with this part, reduces population on visible populated Planet with tag
                HasTag name = "ORGANIC"
            ]
            priority = [[POPULATION_DEFAULT_PRIORITY]]
            effects = [
                SetPopulation value = Value - 0.5
                GenerateSitRepMessage
                    message = "EFFECT_BIOWEAPON"
                    label = "EFFECT_BIOWEAPON_LABEL"
                    icon = "icons/sitrep/bio_weapon_1.png"
                    parameters = [
                        tag = "planet" data = Target.ID
                        tag = "rawtext" data = "0.5"
                        tag = "shippart" data = "SP_DEATH_SPORE"
                    ]
                    empire = Target.Owner
            ]

        EffectsGroup    // monsters use death spores on player planets
            scope = NumberOf number = 1 condition = And [
                InSystem id = Source.SystemID
                Planet
                Species
                OwnedBy affiliation = AnyEmpire
                Stealth high = Source.Detection
                /// @content_tag{ORGANIC} Each part owned by Unowned in system will reduce population on one visible populated empire Planet with tag
                HasTag name = "ORGANIC"
            ]
            activation = And [
                Unowned
                InSystem
            ]
            priority = [[POPULATION_DEFAULT_PRIORITY]]
            effects = [
                SetPopulation value = Value - 0.5
                GenerateSitRepMessage
                    message = "EFFECT_BIOWEAPON"
                    label = "EFFECT_BIOWEAPON_LABEL"
                    icon = "icons/sitrep/bio_weapon_1.png"
                    parameters = [
                        tag = "planet" data = Target.ID
                        tag = "rawtext" data = "0.5"
                        tag = "shippart" data = "SP_DEATH_SPORE"
                    ]
                    empire = Target.Owner
            ]
    ]
    icon = "icons/ship_parts/death-spore.png"

#include "/scripting/macros/upkeep.macros"
#include "/scripting/macros/priorities.macros"
