Sumário

# Funções lógicas

Essa categoria contém as funções lógicas.

### Tratar argumentos não lógicos em funções lógicas

- Zero (0) equivale a FALSO e todos os outros números equivalem a VERDADEIRO.

- Células vazias e células com texto são ignoradas.

- Ocorre um erro #VALOR se todos os argumentos são ignorados.

- Ocorre um erro #VALOR se um dos argumentos é texto direto (e não uma referência a uma célula com texto).

- Erros nos argumentos produzem erros.

Para acessar este comando...

Inserir - Função - Categoria Lógica

### É.NÃO.DISP

Retorna VERDADEIRO se uma célula contém o valor de erro #N/D (valor não disponível).

Se ocorrer um erro, a função retorna FALSO.

#### Sintaxe

É.NÃO.DISP(Valor)

Valor é o valor ou a expressão que deverá ser testada.

#### Exemplo

=É.NÃO.DISP(D3) retorna FALSO.

### SEERRO

Retorna o valor se a célula não tiver um erro ou o valor alternativo se existir erro.

Esta função está disponível desde o LibreOffice 4.0.

#### Sintaxe

SEERRO(Valor; Valor_alternativo)

valor é o valor ou expressão a retornar se não for nem resultar em erro.

valor_alternativo é o valor ou expressão a retornar se valor for ou resultar num erro.

#### Exemplo

=SEERRO(C8;C9) onde a célula C8 contém =1/0 retorna o valor de C9, por que 1/0 é um erro.

=SEERRO(C8;C9) onde a célula C8 contém =13 retorna 13, por que o valor da célula C8 não é um erro.

## SES

SES é uma função SE múltipla.

## PARÂMETRO

A função PARÂMETRO compara expressão com valor1 até valorN e retorna o resultado que pertence ao primeiro valor que igualar a expressão. Se não houver verificação e o resultado padrão for dado, este valor é retornado.

## E

Retorna VERDADEIRO se todos os argumentos forem VERDADEIROs. Se um dos elementos for FALSO, esta função retornará o valor FALSO.

Os argumentos podem ser expressões lógicas (VERDADEIRO, 1<5, 2+3=7, B8<10), que retornam valores lógicos, ou matrizes (A1:C3) contendo valores lógicos.

#### Sintaxe

E(Lógico 1 [; Lógico 2 [; … [; Lógico 255]]])

Lógico 1 ; Lógico 2; … ; Lógico 255 são valores lógicos, referências a células ou intervalos de células contendo valores lógicos.

Esta função ignora qualquer texto ou célula vazia num intervalo de dados. Se suspeitar de resultados errados desta função, procure por texto nos intervalos de dados. Para destacar o conteúdo do texto num intervalo de dados, use o recurso destaque de valor .

#### Exemplo

Os valores lógicos das entradas 12<13, 14>12 e 7<6 devem ser verificados:

=E(12<13;14>12;7<6) retorna FALSO.

=E (FALSO();VERDADEIRO()) retorna FALSO.

A fórmula de matriz {=E(B1:B10;C1:C10)} produz um valor unidimensional de VERDADEIRO quando todos os componentes de B1:B10 e C1:C10 são VERDADEIRO. A expressão de matriz acima não produz o E lógico por elemento e, portanto, não produz uma matriz de valores lógicos. Para calcular um E lógico de matrizes por elemento, use o operador * no contexto de matriz. No exemplo, insira {=B1:B10*C1:C10}.

## FALSO

Retorna o valor lógico FALSO. A função FALSO() não requer argumentos e sempre retorna o valor lógico FALSO.

#### Sintaxe

FALSO()

#### Exemplo

=FALSO() retorna FALSO

=NÃO(FALSO()) retorna VERDADEIRO

## NÃO

Complementa (inverte) um valor lógico.

#### Sintaxe

NÃO(ValorLógico)

ValorLógico é qualquer valor a ser complementado.

#### Exemplo

=NÃO(A). Se A=VERDADEIRO então NÃO(A) será FALSO.

## OU

Retornará VERDADEIRO se pelo menos um argumento for VERDADEIRO. Essa função retornará o valor FALSO se todos os argumentos tiverem o valor lógico FALSO.

Os argumentos podem ser expressões lógicas (VERDADEIRO, 1<5, 2+3=7, B8<10), que retornam valores lógicos, ou matrizes (A1:C3) contendo valores lógicos.

#### Sintaxe

OU(Lógico 1 [; Lógico 2 [; … [; Lógico 255]]])

Lógico 1 ; Lógico 2; … ; Lógico 255 são valores lógicos, referências a células ou intervalos de células contendo valores lógicos.

Esta função ignora qualquer texto ou célula vazia num intervalo de dados. Se suspeitar de resultados errados desta função, procure por texto nos intervalos de dados. Para destacar o conteúdo do texto num intervalo de dados, use o recurso destaque de valor .

#### Exemplo

Os valores lógicos das entradas 12<11; 13>22, e 45=45 devem ser verificados.

=OU(12<11;13>22;45=45) retorna VERDADEIRO.

=OU(FALSO();VERDADEIRO()) retorna VERDADEIRO.

A fórmula de matriz {=OU(B1:B10;C1:C10)} produz um valor unidimensional de FALSO quando todos os componentes de B1:B10 e C1:C10 são FALSO. A expressão de matriz acima não produz o OU lógico por elemento e, portanto, não produz uma matriz de valores lógicos. Para calcular um OU lógico de matrizes por elemento, use o operador + no contexto de matriz. No exemplo, insira {=B1:B10+C1:C10}.

## SE

Especifica um teste lógico a ser efetuado.

#### Sintaxe

SE(Teste [; [ValorEntão [; [ValorSenão]]])

Teste é qualquer expressão ou valor que pode ser VERDADEIRO ou FALSO.

ValorEntão (opcional) é o valor retornado quando o teste lógico for VERDADEIRO.

ValorSenão (opcional) é o valor retornado caso o teste lógico resulte FALSO.

Nas funções do LibreOffice Calc, os parâmetros marcados como «opcionais» podem ser ignorados apenas quando não se seguir um parâmetro. Por exemplo, em uma função com quatro parâmetros, em que os últimos dois estão marcados como «opcionais», você pode ignorar o parâmetro 4 ou os parâmetros 3 e 4, mas não pode ignorar apenas o parâmetro 3.

#### Exemplo

=SE(A1>5;100;"pequeno demais") Se o valor em A1 é maior que 5, retorna o valor 100; senão, retorna o texto pequeno demis.

=SE(A1>5;;"pequeno demais") Se o valor em A1 é maior que 5, retorna o valor0 por que parâmetros omissos são considerados 0; senão retorna o texto pequeno demais.

=SE(A1>5;100;) Se o valor de A1 é menor que 5, o valor retornado é 0 por que ValorSenão vazio é interpretado como 0; senão retorna 100.

## VERDADEIRO

O valor lógico será definido como VERDADEIRO. A função VERDADEIRO() não requer argumentos e sempre retorna o valor lógico VERDADEIRO.

#### Sintaxe

VERDADEIRO()

#### Exemplo

Se A=VERDADEIRO e B=FALSO, os seguintes exemplos serão exibidos:

=E(A;B) retorna FALSO

=OU(A;B) retorna VERDADEIRO

=NÃO(E(A;B)) retorna VERDADEIRO

## XOU

Retorna VERDADEIRO se um número ímpar de argumentos resultar em VERDADEIRO.

Os argumentos podem ser expressões lógicas (VERDADEIRO, 1<5, 2+3=7, B8<10), que retornam valores lógicos, ou matrizes (A1:C3) contendo valores lógicos.

Esta função está disponível desde o LibreOffice 4.0.

#### Sintaxe

XOU(Lógico 1 [; Lógico 2 [; … [; Lógico 255]]])

Lógico 1 ; Lógico 2; … ; Lógico 255 são valores lógicos, referências a células ou intervalos de células contendo valores lógicos.

#### Exemplo

=XOU (VERDADEIRO();VERDADEIRO()) retorna FALSO

=XOU (VERDADEIRO();VERDADEIRO();VERDADEIRO()) retorna VERDADEIRO

=XOU(FALSO();VERDADEIRO()) retorna VERDADEIRO

Tópicos relacionados

Funções por categoria

♥ Doe para nosso projeto! ♥