Sumário

# Funções financeiras - Parte 1

Esta categoria contém as funções financeiras do LibreOffice Calc.

## AMORDEGRC

Calcula o montante de depreciação para um período de liquidação como amortização decrescente. Ao contrário da função AMORLINC, um coeficiente de depreciação independente da vida depreciável é utilizado aqui.

#### Sintaxe

AMORDEGRC(Custo; DataCompra; PrimeiroPeríodo; ValorResidual; Período; Taxa [; Base])

Custo é o custo de aquisição.

DataCompra é a data da aquisição.

PrimeiroPeríodo é a data final do primeiro período de liquidação.

ValorResidual é o valor residual do capital do ativo no fim da vida depreciável.

Período é o período de liquidação a ser considerado.

Taxa é a taxa de depreciação.

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias num ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um ativo foi adquirido em 2020-02-01 a um custo de 2.000 unidades monetárias. A data de término do primeiro período de liquidação foi 2020-12-31. O valor residual do ativo no final de sua vida depreciável será de 10 unidades monetárias. A taxa de depreciação é de 0,1 (10%) e o ano é calculado usando o método dos EUA (Base 0). Assumindo a depreciação degressiva, qual é o valor da depreciação no quarto período de depreciação?

=AMORDEGRC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0,1; 0) retorna um valor de depreciação de 163 unidades monetárias.

Tenha em conta que a Base 2 não é compatível com o Microsoft Excel. Portanto, se utiliza a Base 2 e exportar seu documento para o formato XLSX, ele retornará um erro ao ser aberto no Excel.

## AMORLINC

Calcula o montante de depreciação para um período de liquidação como amortização linear. Se o ativo do imobilizado for adquirido durante o período de pagamento, será considerado o montante de depreciação proporcional.

#### Sintaxe

AMORLINC(Custo; DataCompra; PrimeiroPeríodo; ValorResidual; Período; Taxa [; Base])

Custo significa os custos de aquisição.

DataCompra é a data da aquisição.

PrimeiroPeríodo é a data final do primeiro período de liquidação.

ValorResidual é o valor residual do capital do ativo no fim da vida depreciável.

Período é o período de liquidação a ser considerado.

Taxa é a taxa de depreciação.

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias num ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um ativo foi adquirido em 2020-02-01 a um custo de 2.000 unidades monetárias. A data de término do primeiro período de liquidação foi 2020-12-31. O valor residual do ativo no final de sua vida depreciável será de 10 unidades monetárias. A taxa de depreciação é de 0,1 (10%) e o ano é calculado usando o método dos EUA (Base 0). Assumindo a depreciação linear, qual é o valor da depreciação no quarto período de depreciação?

=AMORLINC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0,1; 0) retorna um valor de depreciação de 200 unidades monetárias.

Tenha em conta que a Base 2 não é compatível com o Microsoft Excel. Portanto, se utiliza a Base 2 e exportar seu documento para o formato XLSX, ele retornará um erro ao ser aberto no Excel.

## BD

Retorna a depreciação de um ativo para um período especificado usando o método de declínio de saldo fixo.

Essa forma de depreciação é usada se você quiser obter um valor maior de depreciação no início da depreciação (em relação à depreciação linear). O valor da depreciação será reduzido a cada período de depreciação pela depreciação já deduzida do custo inicial.

#### Sintaxe

BD(Custo; ValorResidual; Vida; Período [; Mês])

Custo é o custo inicial de um ativo.

ValorResidual é o valor de um ativo no final da depreciação.

Vida define o período sobre o qual um ativo é depreciado.

Período é a duração de cada período. A duração deve ser inserida na mesma unidade de data que o período de depreciação.

Mês (opcional) denota o número de meses do primeiro ano da depreciação. Se uma entrada não for definida, 12 é usado como padrão.

#### Exemplo

Um sistema de computador com um custo inicial de 25.000 unidades monetárias deve ser depreciado ao longo de um período de três anos. O valor residual deve ser 1.000 unidades monetárias. O primeiro período de depreciação compreende 6 meses. Qual é a depreciação do saldo decrescente fixo do sistema de computador no segundo período, que é um ano inteiro começando do final do primeiro período de seis meses?

=BD(25000; 1000; 3; 2; 6) retorna 11.037,95 unidades monetárias.

## BDD

Retorna a depreciação de um ativo para um período especificado usando o método aritmético em declínio.

Use esta forma de depreciação se você necessita de um valor de depreciação inicial maior em relação à depreciação linear. O valor de depreciação diminui a cada período e é geralmente usado para ativos cuja perda de valor é maior logo após a compra (por exemplo, veículos, computadores). Observe que o valor contábil nunca será zero nesse tipo de cálculo.

#### Sintaxe

BDD(Custo; ValorResidual; Vida; Período [; Fator])

Custo fixa o custo inicial de um ativo.

ValorResidual fixa o valor de um ativo no final de sua vida.

Vida é o número de períodos (por exemplo, anos ou meses) que define quanto tempo o ativo deve ser utilizado.

Período estabelece o período para o qual o valor será calculado.

Fator (opcional) é o fator pelo qual a depreciação diminui. Se não for inserido um valor, o padrão será fator 2.

#### Exemplo

Um sistema de computador com custo inicial de 75.000 unidades monetárias deverá ser depreciado mensalmente num prazo de 5 anos. O valor no final da depreciação deverá ser 1 unidade monetária. O fator é 2.

=BDD(75000;1;60;12;2) = 1.721,81 unidades monetárias. Portanto, a depreciação dupla do saldo no décimo segundo mês após a compra é 1.721,81 unidades monetárias.

## DESC

Calcula o reembolso (desconto) de um título como uma porcentagem.

#### Sintaxe

DESC(Pagamento; Vencimento; Preço; Reembolso [; Base])

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Preço é o preço do título por 100 unidades monetárias do valor nominal.

Reembolso é o valor de reembolso do título por 100 unidades monetárias do valor nominal.

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias num ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um título foi comprado em 25-01-2001; a data de vencimento é 15-11-2001. O preço (preço de compra) é 97, o valor de reembolso é 100. Usando o cálculo do saldo diário (base 3), quanto será a liquidação (desconto)?

=DESC("2001-01-25";"2001-11-15";97;100;3) retornará 0,0372 ou 3,72 por cento.

## DURAÇÃO

Calcula a duração em anos de um título com juros fixos.

#### Sintaxe

DURAÇÃO (Pagamento; Vencimento; Cupom; Lucro; Frequência [; Base])

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Cupom é a taxa de juros anual do cupom (taxa de juros nominal)

Lucro é o lucro anual do título.

Frequência é o número de pagamentos de juros por ano. (1, 2 ou 4).

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias num ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um título foi comprado em 01-01-2001; a data de vencimento é 01-01-2006. A taxa nominal de juros é de 8%. O lucro é de 9,0%. Os juros são pagos duas vezes ao ano (a frequência é 2). Utilizando um cálculo de balanço de juros diário (base 3), qual é a extensão da duração?

=DURACAO("2001-01-01";"2006-01-01";0,08;0,09;2;3) retorna 4,2 anos.

## EFETIVA

Retorna a taxa de juros líquida anual para uma taxa de juros nominal.

Juros nominais referem-se à quantia de juros devidos no final do período de cálculo. Os juros efetivos aumentam de acordo com o número de pagamentos feitos. Em outras palavras, os juros geralmente são pagos em prestações (por exemplo, mensalmente ou trimestralmente) antes do fim do período de cálculo.

#### Sintaxe

TAXA.EFETIVA(Nom; P)

Nom é o juro nominal.

P é o número de períodos de pagamento de juros por ano.

#### Exemplo

Se a taxa de juros nominal anual for 9,75% e quatro períodos de cálculo de juros forem definidos, qual é a taxa de juros real (taxa efetiva)?

=TAXA.EFETIVA(9,75%;4) = 10,11% A taxa anual efetiva é, portanto, 10,11%.

## EFETIVA_ADD

Calcula a taxa de juros anual efetiva com base na taxa de juros nominal e o número de pagamentos de juros por ano.

As funções cujo nome terminem com _ADD ou _EXCEL2003 retornam os mesmos resultados que as funções correspondentes do Microsoft Excel 2003 que não possuem o sufixo. Utilize as funções sem o sufixo para obter os resultados baseados em padrões internacionais.

#### Sintaxe

EFETIVA_ADD(TaxaNominal; NPerA)

TaxaNominal é a taxa de juros anual nominal.

NPerA é o número de períodos de pagamento de juros por ano.

#### Exemplo

Qual a taxa de juros anual efetiva para uma taxa nominal de 5,25% paga trimestralmente.

=EFETIVA_ADD(0,0525;4) retorna 0,053543 ou 5,3534%.

## JUROSACUM

Calcula os juros acumulados de um título no caso de pagamentos periódicos.

#### Sintaxe

JUROSACUM (Emissão; PrimeiroPeríodo; Liquidação; Taxa; [ValorNominal]; Frequência [; Base])

Emissão (obrigatório) é a data de emissão do título.

PrimeiroJuro (obrigatório) é a data do primeiro juro do título.

Liquidação (obrigatório) é a data até a qual os juros acumulados serão calculados.

Taxa (obrigatório) é a taxa de juros nominal anual (taxa de juros do cupom)

ValorNominal (opcional) é o valor nominal do título. Se omitido, usa-se o valor padrão é 1000.

Sempre recomenda-se especificar o valor desejado para o argumento ValorNominal de JUROSACUM, em vez de permitir ao Calc utilizar um valor padrão arbitrário. Isso torna a fórmula mais fácil de entender e manter.

Frequência (obrigatório) é o número de pagamentos de juros por ano. (1, 2 ou 4).

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias num ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um título é emitido em 28-02-2001. O primeiro pagamento dos juros é definido para 31-08-2001. A data de liquidação será 01-05.2001. A taxa será 0,1 ou 10% e o valor nominal será 1000 unidades monetárias. Os juros serão pagos duas vezes ao ano (a frequência será 2). A base será o método norte-americano (0). Quanto serão os juros acumulados?

=JUROSACUM("2001-02-28";"2001-08-31";"2001-05-01";0,1;1000;2;0) retorna 16,94444.

## JUROSACUMV

Calcula os juros acumulados de um título no caso da quitação num único pagamento na data de liquidação.

#### Sintaxe

JUROSACUMV (Emissão; Liquidação; Taxa [; ValorNominal [; Base]])

Emissão (obrigatório) é a data de emissão do título.

Liquidação (obrigatório) é a data até a qual os juros acumulados serão calculados.

Taxa (obrigatório) é a taxa de juros nominal anual (taxa de juros do cupom).

ValorNominal (opcional) é o valor nominal do título. Se omitido, usa-se o valor padrão é 1000.

Sempre recomenda-se especificar o valor desejado para o argumento ValorNominal de JUROSACUM, em vez de permitir ao Calc utilizar um valor padrão arbitrário. Isso torna a fórmula mais fácil de entender e manter.

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias num ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um título foi emitido em 01-04-2001. A data de vencimento foi definida para 15-06-2001. A taxa é 0,1 ou 10% e o valor nominal é 1000 unidades monetárias. A base do cálculo diário/anual será o saldo diário (3). Quanto serão os juros acumulados?

=JUROSACUMV("2001-04-01";"2001-06-15";0,1;1000;3) retorna 20,54795.

## RECEBER

Calcula a quantia recebida que foi paga por um título com juros fixos numa data específica.

#### Sintaxe

RECEBER(Pagamento; Vencimento; Investimento; Desconto [; Base])

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Investimento é o total da compra.

Desconto é o desconto percentual na aquisição do título.

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias num ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Data de liquidação: 15 de fevereiro de 1999, data de vencimento: 15 de maio de 1999, soma do investimento: 1000 unidades monetárias, desconto: 5,75 por cento, base: Saldo diário/360 = 2.

A quantia recebida na data de vencimento é calculada da seguinte forma:

=RECEBER("1999-02-15";"1999-05-15";1000;0,0575;2) retorna 1014,420266.

## SDA

Retorna a taxa de depreciação aritmética em declínio.

Use esta função para calcular o montante de depreciação de um período em relação ao período total de depreciação de um objeto. A depreciação aritmética em declínio reduz o montante de depreciação de período em período numa soma fixa.

#### Sintaxe

SDA(Custo; ValorResidual; VidaÚtil; Período)

Custo é o custo inicial de um ativo.

ValorResidual é o valor de um ativo após depreciação.

VidaÚtil é o período que fixa o intervalo de tempo durante o qual o ativo será depreciado.

Período define o período para o qual a depreciação deverá ser calculada.

#### Exemplo

Um sistema de vídeo que inicialmente custa 50.000 unidades monetárias deverá ser depreciado anualmente num prazo de 5 anos. O valor residual deverá ser 10.000 unidades monetárias. Você deseja calcular a depreciação para o primeiro ano.

=SDA(50000;10000;5;1)=13.333,33 unidades monetárias. A depreciação para o primeiro ano é 13.333,33 unidades monetárias.

Para ter uma visão geral das taxas de depreciação por período, é melhor definir uma tabela de depreciação. Ao inserir as diferentes fórmulas de depreciação disponíveis no LibreOffice Calc uma ao lado da outra, você poderá escolher a forma de depreciação mais apropriada. Insira a tabela da seguinte forma:

| A | B | C | D | E
1 | Custo inicial | Valor residual | Vida útil | Período de tempo | Deprec. SDA
2 | 50.000 unidades monetárias | 10.000 unidades monetárias | 5 | 1 | 13,333.33 unidades monetárias
3 |  |  |  | 2 | 10.666,67 unidades monetárias
4 |  |  |  | 3 | 8.000 unidades monetárias
5 |  |  |  | 4 | 5.333,33 unidades monetárias
6 |  |  |  | 5 | 2.666,67 unidades monetárias
7 |  |  |  | 6 | 0,00 unidades monetárias
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | >0 |  |  | Total | 40.000,00 unidades monetárias

A fórmula em E2 é a seguinte:

=SDA($A$2;$B$2;$C$2;D2)

Essa fórmula será duplicada na coluna E até a célula E11 (selecione a célula E2 e arraste para baixo o canto inferior direito com o mouse).

A célula E13 contém a fórmula usada para verificar o total dos montantes de depreciação. A função SOMASE é usada, pois os valores negativos em E8:E11 não devem ser considerados. A condição >0 estará contida na célula A13. A fórmula da célula E13 será a seguinte:

=SOMASE(E2:E11;A13)

Agora, veja a depreciação para um período de 10 anos, ou um valor residual de 1 unidade monetária, ou insira um custo inicial diferente, e assim por diante.

## TIR

Calcula a taxa interna de retorno para um investimento. Os valores representam valores de fluxo de caixa em intervalos regulares; pelo menos um valor deve ser negativo (pagamentos) e pelo menos um valor deve ser positivo (receita).

Se os pagamentos ocorrerem em intervalos irregulares, utilize a função XTIR.

#### Sintaxe

TIR(Valores [; Estimativa])

Valores representa uma matriz que contém os valores.

Estimativa (opcional) é o valor estimado. Um método iterativo será utilizado para calcular a taxa interna de retorno. Se você somente puder fornecer alguns valores, informe uma estimativa inicial para permitir a iteração.

Esta função ignora qualquer texto ou célula vazia num intervalo de dados. Se suspeitar de resultados errados desta função, procure por texto nos intervalos de dados. Para destacar o conteúdo do texto num intervalo de dados, use o recurso destaque de valor .

#### Exemplo

Assumindo que o conteúdo das células é A1=-10000, A2=3500, A3=7600 e A4=1000, a fórmula =TIR(A1:A4) resulta em 11,33%.

Devido ao método iterativo usado, é possível que TIR falhe e retornar o Erro 523, com "Erro: o Cálculo não converge" na barra de status. Nesse caso, tente outro valor para Estimativa.

## VP

Retorna o valor real de um investimento resultante de uma série de pagamentos regulares.

Use esta função para calcular a quantia em dinheiro necessária para ser investida a uma taxa fixa hoje, de modo a receber uma quantia específica, uma anuidade, num número determinado de períodos. Você também pode determinar quanto dinheiro deve restar depois do fim do período. Especifique também se a quantia deverá ser paga no início ou no fim de cada período.

Insira esses valores como números, expressões ou referências. Se, por exemplo, os juros são pagos anualmente a 8%, mas você deseja usar o mês como período, insira 8%/12 em Taxa e o LibreOffice Calc automaticamente calculará o fator correto.

#### Sintaxe

VP(Taxa; NPER; Pgto [; VF [; Tipo]])

Taxa define a taxa de juros por período.

NPer é o número total de períodos (período de pagamento).

Pgto é o pagamento regular feito por período.

VF (opcional) define o valor futuro restante após o pagamento da última parcela.

Tipo (opcional) denota a data de vencimento para pagamentos. Tipo = 1 significa que vence no início do período e Tipo = 0 (padrão) significa que vence no final do período.

Nas funções do LibreOffice Calc, os parâmetros marcados como «opcionais» podem ser ignorados apenas quando não se seguir um parâmetro. Por exemplo, em uma função com quatro parâmetros, em que os últimos dois estão marcados como «opcionais», você pode ignorar o parâmetro 4 ou os parâmetros 3 e 4, mas não pode ignorar apenas o parâmetro 3.

#### Exemplo

Qual é o valor real de um investimento, se 500 unidades monetárias são pagas mensalmente e a taxa de juros anuais é 8%? O período de pagamento é de 48 meses e 20.000 unidades monetárias devem restar no final do período de pagamento.

=VP(8%/12;48;500;20000) = -35.019,37 unidades monetárias. Nas condições citadas, você deve depositar 35.019,37 unidades monetárias hoje, caso queira receber 500 unidades monetárias por mês durante 48 meses e ter 20.000 unidades monetárias sobrando no final. Verificando o cálculo, tem-se 48 x 500 unidades monetárias + 20.000 unidades monetárias = 44.000 unidades monetárias. A diferença entre este montante e as 35.000 unidades monetárias depositadas representa os juros pagos.

Se inserir referências em vez desses valores na fórmula, você poderá calcular qualquer número de cenários "Se-então". Nota: as referências às constantes devem ser definidas como referências absolutas. Exemplos desse tipo de aplicação são encontrados nas funções de depreciação.

## ÉPGTO

Calcula o nível de juros para prestações fixas de amortização.

#### Sintaxe

ÉPGTO(Taxa; Período; TotalPeríodos; Investimento)

Taxa define a taxa de juros periódica.

Período é o número de prestações para o cálculo de juros.

TotalPeríodos é o número total de períodos de prestação.

Investimento é o montante do investimento.

#### Exemplo

Deve-se obter o nível dos juros após 1,5 anos para um crédito de 120.000 unidades monetárias com prestações mensais num período de dois anos e com uma taxa de juros anual de 12%.

=ÉPGTO(1%;18;24;120000) = -300 unidades monetárias. O juro mensal após 1,5 anos soma 300 unidades monetárias.

Funções financeiras - Parte 2

Funções financeiras - Parte 3

Funções por categoria

♥ Doe para nosso projeto! ♥